Subject: ｃｓｖデータの複数結合をするには
========================================
From: ｐａｚｕ
Date: 2001/09/11(火) 11:21:03

はじめて質問します、pazuといいます。
環境はexcel2000を使用しています。

excelに作ったボタンを1クリックしたら、
c:\wk\内にある複数個のcsvデータをc:\wk\new\uriage.csvの名前でデータを
1つに結合したいのです。
あと、そのボタンを何度押しても２重計上されないようにしたいので、
ボタンをクリックされたらc:\wk\内にcsvデータが１件でもあるかチェックします。
　存在すればc:\wk\new\にuriage.csvを作成し、c:\wk\内のすべてのcsvデータを削除します。
　存在しない場合はuriage.csvを作成しないようにしたいのです。

どうかよろしくお願いします。
========================================
From: Ron
E-Mail: ebako@h9.dion.ne.jp
Date: 2001/09/11(火) 22:56:04

こんばんは。
こんな感じでどうでしょう。
Private Sub CommandButton1_Click()

    Const myPath As String = "c:\wk\"
    Const myNewCSV As String = "new\uriage.csv"
    Dim myFName As String
    Dim FNo As Integer
    Dim myData() As Variant
    Dim i As Integer
    Dim j As Integer
    
    ChDir myPath
    FNo = FreeFile
    myFName = Dir("*.csv")
    Do Until myFName = ""
        Open myFName For Input As FNo
        Do Until EOF(FNo)
            i = i + 1
            ReDim Preserve myData(1 To i) As Variant
            Line Input #FNo, myData(i)
        Loop
        Close #FNo
        Kill myFName　
        myFName = Dir()
    Loop
    
    Open myNewCSV For Output As #FNo
    For j = 1 To i
        Print #FNo, myData(j)
    Next
    Close #FNo
    

End Sub
お試しください。
では。
========================================
From: pazu
Date: 2001/09/11(火) 23:36:13

RONさん、さっそくのレスありがとうございます。
さっそく使って見ました。
1回目ボタンをクリックしたら、イメージ通りのものになりましたが、
そのまま、連続で2回目をクリックしたら（c:\wk内にはcsvデータが無い状態です。）
Open myNewCSV For Output As #FNo　でエラーがでました。
何か回避方法はあるのでしょうか。よろしくお願いします。
========================================
From: Ron
E-Mail: ebako@h9.dion.ne.jp
Date: 2001/09/11(火) 23:47:54

こんばんは。
エラーがでました？
こちらでは問題なかったのですが。
それでは、１行追加して下さい。

Private Sub CommandButton1_Click() 

    Const myPath As String = "c:\wk\" 
    Const myNewCSV As String = "new\uriage.csv" 
    Dim myFName As String 
    Dim FNo As Integer 
    Dim myData() As Variant 
    Dim i As Integer 
    Dim j As Integer 
     
    ChDir myPath 
    FNo = FreeFile 
    myFName = Dir("*.csv") 
　　<red>>If myFName = "" Then Exit Sub</red>
    Do Until myFName = "" 

お試し下さい。
では。
========================================
From: pazu
Date: 2001/09/12(水) 00:52:21
Solved: on

Ronさん、世界がえらいこっちゃになってる最中
早いレス本当にありがとうございました。
１行入れることにより、イメージ通りになりました。

さっそく、明日会社で利用したいと思います。
ありがとうございました。

ps:テロはひどいですね。ニュースにくぎ付けです。